build_dev.gradle

plugins {
	id 'fabric-loom' version '1.2-SNAPSHOT'
	id 'maven-publish'
}

version = project.mod_version
group = project.maven_group

repositories {
	// Add repositories to retrieve artifacts from in here.
	// You should only use this when depending on other mods because
	// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
	// See https://docs.gradle.org/current/userguide/declaring_repositories.html
	// for more information about repositories.

	// Complete Config repos
	maven {
		url 'https://jitpack.io'
	}
	maven {
		url "https://maven.terraformersmc.com/"
	}
	maven {
		url "https://maven.shedaniel.me/"
	}
	maven {
		url "https://maven.siphalor.de/"
	}
	maven {
		url "https://maven.isxander.dev/releases"
	}
	maven {
		name = "ParchmentMC"
		url = "https://maven.parchmentmc.net/"
	}
	maven {
		url "https://cursemaven.com"
	}
	maven {
		name = 'Forge'
		url = 'https://maven.minecraftforge.net/'
	}
	flatDir {
		dir 'libs'
	}
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings(loom.layered {
		it.parchment("org.parchmentmc.data:parchment-${minecraft_version}:${parchment_version}@zip")
		it.officialMojangMappings { nameSyntheticMembers = false }
	})
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Fabric API. This is technically optional, but you probably want it anyway.
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	//include(modImplementation("ForgeConfigAPIPort:ForgeConfigAPIPort:v8.0.0-1.20.1-Fabric"))
	//using https://www.curseforge.com/minecraft/mc-mods/forge-config-api-port-fabric/files/4583000
	include(modImplementation("curse.maven:forge-config-api-port-fabric-547434:4583000"))
	//include(modImplementation("fuzs.forgeconfigapiport:forgeconfigapiport-fabric:v8.0.0-1.20.1-Fabric"))

	// Forge Deps. For dependency libraries required at compile, you'll have to add an implementation for them as well.
	implementation "net.minecraftforge:forge:${minecraft_version}-${project.forge_version}:universal"
	implementation "net.minecraftforge:javafmllanguage:${minecraft_version}-${project.forge_version}"
	implementation "net.minecraftforge:fmlcore:${minecraft_version}-${project.forge_version}"
	implementation "net.minecraftforge:fmlloader:${minecraft_version}-${project.forge_version}"
	implementation "net.minecraftforge:eventbus:${project.forge_event_bus_version}"
	implementation "net.minecraftforge:mergetool:${project.forge_merge_tool_version}:api"
	implementation "com.electronwill.night-config:core:${project.nightconfig_core_version}"
}

//If there's mixins
loom {
	accessWidenerPath = file("src/main/resources/coroutil.accesswidener")
	mixin {
		defaultRefmapName = "${project.mod_id}.refmap.json"
	}
}

sourceSets {
	main {
		java {
            exclude "com/corosus/${project.mod_id}/api/forge/**"
			exclude "com/corosus/${project.mod_id}/loader/forge/**"
		}
	}
}

base {
	archivesName = "${project.archives_base_name}-fabric"
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "mod_id": project.mod_id, "version": project.version, "mod_name": project.mod_name, "mod_description": project.mod_description, "mod_authors": project.mod_authors, "mod_license": project.mod_license
	}
	
	exclude("META-INF/mods.toml")
	exclude("META-INF/accesstransformer.cfg")
}

tasks.withType(JavaCompile).configureEach {
	// Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
	it.options.release = 17
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	//withSourcesJar()

	sourceCompatibility = JavaVersion.VERSION_17
	targetCompatibility = JavaVersion.VERSION_17
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}"}
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}