build.gradle

/*
 * Copyright 2018 Google LLC
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

buildscript {
    // Define versions in a single place
    ext {
        // Sdk and tools
        compileSdkVersion = 31
        minSdkVersion = 21
        targetSdkVersion = 31

         // App dependencies
        activityComposeVersion = '1.3.0-rc02'
        accessibilityTestFrameworkVersion = '4.0.0'
        appCompatVersion = '1.4.1'
        benchmarkVersion = '1.1.0-rc02'
        coilVersion = '2.0.0'
        composeThemeAdapterVersion = '1.1.1'
        composeVersion = '1.2.0-beta02'
        constraintLayoutComposeVersion = '1.0.0-alpha08'
        constraintLayoutVersion = '2.1.3'
        coreTestingVersion = '2.1.0'
        coroutinesVersion = "1.6.1"
        espressoVersion = '3.4.0'
        fragmentVersion = '1.4.1'
        gradleVersion = '7.2.0'
        gsonVersion = '2.9.0'
        hiltVersion = '2.41'
        junitVersion = '4.13.2'
        kotlinVersion = '1.6.21'
        ktlintVersion = '0.40.0'
        ktxVersion = '1.7.0'
        lifecycleVersion = '2.4.1'
        materialVersion = '1.5.0'
        navigationVersion = '2.4.1'
        okhttpLoggingVersion = '4.9.3'
        pagingVersion = '3.1.1'
        profileInstallerVersion = '1.2.0-beta01'
        recyclerViewVersion = '1.3.0-alpha02'
        retrofitVersion = '2.9.0'
        roomVersion = '2.4.2'
        runnerVersion = '1.0.1'
        testExtJunit = '1.1.3'
        tracingVersion = '1.1.0'
        truthVersion = '1.1.3'
        uiAutomatorVersion = '2.2.0'
        viewModelComposeVersion = '1.0.0-alpha07'
        viewPagerVersion = '1.0.0'
        workVersion = '2.7.1'
    }

    repositories {
        google()
        mavenCentral()
    }

    dependencies {
        classpath "com.android.tools.build:gradle:$gradleVersion"
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath "androidx.navigation:navigation-safe-args-gradle-plugin:$navigationVersion"
        classpath "com.google.dagger:hilt-android-gradle-plugin:$hiltVersion"
    }
}

plugins {
    id "com.diffplug.spotless" version "6.4.1"
}

allprojects {
    repositories {
        google()
        mavenCentral()
    }
}

spotless {
    kotlin {
        target "**/*.kt"
        ktlint(ktlintVersion).userData(['max_line_length': '100'])
    }
}

subprojects {
    tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).configureEach {
        kotlinOptions {
            jvmTarget = "1.8"
            // Use experimental APIs
            freeCompilerArgs += '-Xopt-in=kotlin.RequiresOptIn'
        }
    }
}