build.gradle

buildscript {
    ext {
        assetPipelineVersion = "2.7.2"
        jobDslVersion = "1.79"
    }
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'io.ratpack:ratpack-gradle:1.2.0'
        classpath "com.github.jengelman.gradle.plugins:shadow:1.2.2"
        classpath "com.bertramlabs.plugins:asset-pipeline-gradle:${assetPipelineVersion}"
        classpath "com.bertramlabs.plugins:less-asset-pipeline:${assetPipelineVersion}"
    }
}

// The “ratpack” plugin applies the “application” plugin, making it easy to create a standalone application.
// See: http://gradle.org/docs/current/userguide/application_plugin.html
apply plugin: "io.ratpack.ratpack-groovy"
apply plugin: "com.github.johnrengelman.shadow"
apply plugin: "asset-pipeline"

// The “ratpack” plugin is IDEA aware.
// It will create a run configuration in IDEA to launch your app in your IDE, with hot reloading.
apply plugin: "idea"
idea {
    project {
        jdkName "1.8"
        languageLevel "1.8"
        ipr {
            withXml { provider ->
                def node = provider.asNode()
                //configure git support for the project in idea
                node.component.find { it.'@name' == 'VcsDirectoryMappings' }?.mapping[0].'@vcs' = 'Git'
            }
        }
    }
}

apply plugin: "eclipse"

repositories {
  mavenCentral()
  maven { url "https://repo.jenkins-ci.org/releases/" }
}

configurations.all {
    exclude module: "groovy"
}

dependencies {
    // Default SLF4J binding. Note that this is a blocking implementation.
    // See here for a non blocking appender http://logging.apache.org/log4j/2.x/manual/async.html
    runtime 'org.slf4j:slf4j-simple:1.7.7'
    compile "org.jenkins-ci.plugins:job-dsl-core:${jobDslVersion}"

    compile "com.bertramlabs.plugins:ratpack-asset-pipeline:${assetPipelineVersion}"
    runtime "com.bertramlabs.plugins:less-asset-pipeline:${assetPipelineVersion}"

    testCompile "org.spockframework:spock-core:1.0-groovy-2.4"
}

shadowJar {
    manifest {
        attributes 'Implementation-Version': jobDslVersion
    }
}

task stage {
    dependsOn shadowJar
}