-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy pathlz49decrunch_v001.asm
138 lines (119 loc) · 1.66 KB
/
lz49decrunch_v001.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
;
; LZ49 decrunch
; input
; hl compressed data adress
; de output adress of data
;
; output
; hl last adress of compressed data read (you must inc once for LZ49 stream)
; de last adress of decrunched data write +1
; bc always 3
; a always zero
; ixl undetermined
; flags (inc a -> 0)
;org #8000
;; CALL #8000,source,destination
; di
;
;; parameters
; ld h,(ix+3)
; ld l,(ix+2)
; ld d,(ix+1)
; ld e,(ix+0)
;
; call LZ49_decrunch
;
; ei
; ret
LZ49_decrunch
ldi
ld b,0
nextsequence
ld a,(hl)
inc hl
ld ixl,a
and #70
jr z,lzunpack ; no litteral bytes
rrca
rrca
rrca
rrca
ld c,a
cp 7 ; more bytes for length?
jr nz,copyliteral
getadditionallength
ld a,(hl)
inc hl
inc a
jr nz,lengthnext
inc b
dec bc
jr getadditionallength
lengthnext
dec a
add a,c
ld c,a
ld a,b
adc a,0
ld b,a ; bc=length
copyliteral
ldir
lzunpack
ld a,ixl
and #F
add 3
ld c,a
cp 18 ; more bytes for length?
jr nz,readoffset
getadditionallengthbis
ld a,(hl)
inc hl
inc a
jr nz,lengthnextbis
inc b
dec bc
jr getadditionallengthbis
lengthnextbis
dec a
add a,c
ld c,a
ld a,b
adc a,0
ld b,a ; bc=length
readoffset
ld a,ixl
add a
jr c,extendedoffset
; read encoded offset
ld a,(hl)
inc a
ret z ; LZ48 end with zero offset
inc hl
push hl
ld l,a
ld a,e
sub l
ld l,a
ld a,d
sbc a,0
ld h,a
; source=dest-copyoffset
ldir
pop hl
jr nextsequence
extendedoffset
ld a,(hl)
inc hl
push hl
inc a
ld l,a
ld a,e
sub l
ld l,a
ld a,d
sbc a,1
ld h,a
; source=dest-copyoffset
ldir
pop hl
jr nextsequence